Viele Word-Dokumente zusammenführen; wie geht dem am besten?

[t4.]

Folgendes Problem: Ich habe hier > 700 einzelne zwei- bis dreiseitige Word-Dokumente. Die Dateien sind an den ersten drei Stellen des Dateinamens fortlaufend durchnumeriert:

001_Abc_Xyz.doc

002_Vxf_Qui.doc

003_Aac_Zaz.doc

004_ ...

und ich möchte diese Dateien in der numerierten Reihenfolge zu einem neuen (ggf auch nur temporären) Dokument verbinden. Die Dateien sind vom Format her absolut gleich aufgebaut (Seitenränder, Kopf- und Fußzeile, etc). Gibt's dafür irgendein Tool oder sogar eine Word-Funktion? Bevor Tipps in Richtung anderer Produkte oder Betriebssysteme kommen: Es muß Win XP und es muß Word 2002 sein ...

[huegenbegger]

mit Filialdokumenten arbeiten, ich wünsch Dir viel Erfolg

Word und die Verwaltung vieler Dateien, oha!

[brianjones71]

Wenn sie absolut gleich formatiert sind, gehst du über Extras-Dokumente vergleichen und zusammenführen!

Jo oder über Zentral- und Filialdokumenten!

Bearbeitet 26. Juli 2007 von brianjones71

[t4.]

Uh, Filialdokumente sind ja mal echt ... geht gar nicht.

Aber Extras/Dokumente/vergleichen und zusammenführen geht ebensowenig; ich will vermeiden, jedes einzelne der 699 Folgedokumente manuell einzeln anklicken zu müssen ...

Aber Danke für die Tipps - gibt's noch was Anderes?

[brianjones71]

Tut mir leid, aber DU hast es so gewollt.

Erstmal alle Dateien sind in einem Verzeichnis? Habe hier ein script für dich, dafür solltest du alle Docs in ein Verzeichnis c:\Ablage legen!

Word öffnen alt+F11 drücken Visual Basic öffnet sich. Jetzt gehst du auf einfügen-Modul. Dort kopierst du diesen Code ein.

Private Const Verzeichnis = "C:\Ablage"

Private Const Filter = "*.doc"

Sub DateienKonkatinieren1()

Q = Chr(34) 'Gänsefüsschen

Dim Anzahl As Integer, sCount As Integer, fCount As Integer, fListe As String

If Documents.Count > 0 Then Dokument = ActiveDocument.FullName

On Error Resume Next

chk = Dir(Verzeichnis, vbDirectory + vbVolume)

If Err.Number > 0 Then

MsgBox "Kein Zugriff auf Verzeichnis " & Q & Verzeichnis & Q & "."

Exit Sub

End If

On Error GoTo 0

Pfad = Verzeichnis & "\" & Filter

chk = Dir(Pfad)

If chk = "" Then 'Wenn keine entsprechenden Dateien im Verzeichnis

MsgBox "Kein Dateien im Verzeichnis " & Q & Verzeichnis & Q & "."

Exit Sub

End If

WordBasic.DisableAutoMacros 1 'Automakros ausschalten

With Application.FileSearch 'Dateien im vorgegebenen Verzeichnis suchen

.LookIn = Verzeichnis

.FileName = Filter

.Execute SortBy:=msoSortByFileName

Anzahl = .FoundFiles.Count

For Each aDok In .FoundFiles

dsname = Dir(aDok) 'Sortiert versteckte Dateien aus

If Not aDok = Dokument And Not Left(dsname, 1) = "~" And Not dsname = "" Then

sCount = sCount + 1 'Zähler für die zu verarbeitenden Dateien

If Go4It(aDok) > 0 Then

fCount = fCount + 1 'Z. für D., welche nicht verarbeitet werden konnten

fListe = fListe & vbCr & aDok 'Fehlerliste

End If

End If

Next

End With

ms = sCount & " Dokumente gefunden." & vbCr

ms = ms & sCount - fCount & " Dokumente verarbeitet."

If fCount > 0 Then

ms = ms & vbCr & vbCr & "Bei folgenden Dokumenten ist ein Fehler aufgetreten:"

ms = ms & vbCr & fListe

End If

WordBasic.DisableAutoMacros 0 'Automakros einschalten

Application.ScreenUpdating = True

MsgBox ms, vbInformation

End Sub

Private Function Go4It(aDok) As Integer

Dim oRange As Range

Set oRange = ActiveDocument.Paragraphs.Last.Range

If Not ActiveDocument.Content.Text = Chr(13) Then 'wenn nicht erstes Dokument

oRange.InsertBreak Type:=wdSectionBreakNextPage 'Abschnittwechsel einbringen

End If

On Error Resume Next

oRange.InsertFile FileName:=aDok 'nächstes Quelldokument einfügen

Fehler = Err.Number

On Error GoTo 0

Go4It = Fehler

End Function

Dann gehst du oben auf den Playbutton oder drückst F5. Ausführen, jetzt ist dein Dokument1, die Gesamtdatei aller Docs.

Viel Spass! und

Bearbeitet 26. Juli 2007 von brianjones71

[t4.]

Probier ich morgen früh aufffe Schicht gleich aus!

GSF weiß doch alles (hoffentlich ...)

[brianjones71]

Also bei mir funzt es super!

[t4.]

brianjones, ich will ein Kinn von dir!

D A N K Ä H !!!!!

Das spart mir in den nächsten Wochen einige Stunden ...

Ich hoffe, wir sehen uns mal auf ein oder drei Bier oder so!

[brianjones71]

brianjones, ich will ein Kinn von dir!

Jau geil, so ein langes, wie der Schumi es hat?

Schönes WE und

[t4.]

Na gut, dann halt ein Rind. Oder so.